Close Positions Current Symbol - скрипт для MetaTrader 5

Описание скрипта

Данный скрипт закрывает все позиции по символу на график которого он был брошен. Скрипт копирует Magic number у закрываемой позиции, при этом своего Magic number скрипт не имеет.

Например по символу 'USDJPY' открыты несколько позиций:

• позиция #1 была открыта вручную и поэтому её Magic равен '0'
• позиция #2 была открыта советников и её Magic равен '300'

Код скрипта:

//+------------------------------------------------------------------+
//|                               Close Positions Current Symbol.mq5 |
//|                              Copyright © 2020, Vladimir Karputov |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2020, Vladimir Karputov"
#property version   "1.000"
#include <Trade\PositionInfo.mqh>
#include <Trade\Trade.mqh>
CPositionInfo  m_position;                   // trade position object
CTrade         m_trade;                      // trading object
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions
      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties
         if(m_position.Symbol()==Symbol())
           {
            m_trade.SetExpertMagicNumber(m_position.Magic());
            if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol
               Print(__FILE__," ",__FUNCTION__,", ERROR: ","CTrade.PositionClose ",m_position.Ticket());
           }
  }
//+------------------------------------------------------------------+